一、前言
进入新世纪的快节奏生活时代，工程师在先进的电子设计领域里需要应对更多的挑战，比如：更快更好的进行电路设计从而节省时间及精力，然而传统的电路设计越来越跟不上时代的节奏，费时且又力不从心，因此需要掌握一些的先进仿真设计工具是未来新生代工程师必不可少的技能，本节简单介绍笔者多年前就学习过的TINA 设计工具（记得在10年前笔者曾在Arrow任职时期有问过TI 要Pspice模型，从而导致TI 对TINA有兴趣，后面才产生了TINA-TI定制版）。本节采用TINA-TI 免费版的工具讲述如何在TINA-TI库里创建一个LM386模型。
二、准备资料
我们知道在TINA-TI 的库是没有LM386这个器件，因此我们需要亲自创建一个并调用以便于后续简单的功率放大器的电路仿真设计，此部分内容需要读者自行了解并学习简单的Pspice语法，最好能够自己动手编写，然而大部分工程师不是器件物理师，对Pspice模型理解的不透也无法获得具体的参数，以下为国外某人编写的LM386 subcircuit model如下：
进入新世纪的快节奏生活时代，工程师在先进的电子设计领域里需要应对更多的挑战，比如：更快更好的进行电路设计从而节省时间及精力，然而传统的电路设计越来越跟不上时代的节奏，费时且又力不从心，因此需要掌握一些的先进仿真设计工具是未来新生代工程师必不可少的技能，本节简单介绍笔者多年前就学习过的TINA 设计工具（记得在10年前笔者曾在Arrow任职时期有问过TI 要Pspice模型，从而导致TI 对TINA有兴趣，后面才产生了TINA-TI定制版）。本节采用TINA-TI 免费版的工具讲述如何在TINA-TI库里创建一个LM386模型。
二、准备资料
我们知道在TINA-TI 的库是没有LM386这个器件，因此我们需要亲自创建一个并调用以便于后续简单的功率放大器的电路仿真设计，此部分内容需要读者自行了解并学习简单的Pspice语法，最好能够自己动手编写，然而大部分工程师不是器件物理师，对Pspice模型理解的不透也无法获得具体的参数，以下为国外某人编写的LM386 subcircuit model如下：
* CONNECTIONS: Gain 1
* | Non-Inverting Input
* | | Inverting Input
* | | | Gnd
* | | | | Vout
* | | | | | Vs
* | | | | | | Bypass
* | | | | | | | Gain 8
* | | | | | | | |
* 1 2 3 4 5 6 7 8
.SUBCKT LM386 g1 inn inp gnd out vs byp g8
* input emitter-follower buffers:
q1 gnd inn 10011 ddpnp
r1 inn gnd 50k
q2 gnd inp 10012 ddpnp
r2 inp gnd 50k
* differential input stage, gain-setting
* resistors, and internal feedback resistor:
q3 10013 10011 10008 ddpnp
q4 10014 10012 g1 ddpnp
r3 vs byp 15k
r4 byp 10008 15k
r5 10008 g8 150
r6 g8 g1 1.35k
r7 g1 out 15k
* input stage current mirror:
q5 10013 10013 gnd ddnpn
q6 10014 10013 gnd ddnpn
* voltage gain stage & rolloff cap:
q7 10017 10014 gnd ddnpn
c1 10014 10017 15pf
* current mirror source for gain stage:
i1 10002 vs dc 5m
q8 10004 10002 vs ddpnp
q9 10002 10002 vs ddpnp
* Sziklai-connected push-pull output stage:
q10 10018 10017 out ddpnp
q11 10004 10004 10009 ddnpn 100
q12 10009 10009 10017 ddnpn 100
q13 vs 10004 out ddnpn 100
q14 out 10018 gnd ddnpn 100
* generic transistor models generated
* with MicroSim's PARTs utility, using* default parameters except Bf:
.MODEL ddnpn NPN(Is=10f Xti=3 Eg=1.11 Vaf=100
+ Bf=400 Ise=0 Ne=1.5 Ikf=0 Nk=.5 Xtb=1.5 Var=100
+ Br=1 Isc=0 Nc=2 Ikr=0 Rc=0 Cjc=2p Mjc=.3333
+ Vjc=.75 Fc=.5 Cje=5p Mje=.3333 Vje=.75 Tr=10n
+ Tf=1n Itf=1 Xtf=0 Vtf=10)
.MODEL ddpnp PNP(Is=10f Xti=3 Eg=1.11 Vaf=100
+ Bf=200 Ise=0 Ne=1.5 Ikf=0 Nk=.5 Xtb=1.5 Var=100
+ Br=1 Isc=0 Nc=2 Ikr=0 Rc=0 Cjc=2p Mjc=.3333
+ Vjc=.75 Fc=.5 Cje=5p Mje=.3333 Vje=.75 Tr=10n
+ Tf=1n Itf=1 Xtf=0 Vtf=10)
.ENDS
三、创建器件
有了这个subcircuit model，因此我们需要导入TINA-TI里，进行创建能够使用的器件，见下图：
1,导入.cir文件或者其他LIB文件都行，本节演示导入.cir文件
2，编译存档，注意保存路径。
3，在Tool下找到新建宏模型向导，按照向导一步步设置。
4，在新建宏模型向导里选择自动匹配或者自行修正放大器外观
5，在新建宏模型向导里选择保存路径，方便调用，注意这个时候文件名称已经变成.TSM文档了。
6，保存后会弹出对话框，问你是不是现在插入还是后续插入，记得保存的路径，否则找不到文件了。
四、调用验证。
五、结束语
TINA-TI是一款非常强大的电路仿真软件，在信号处理尤其是模拟电路设计是非常好用的电路仿真软件，值得学习和拥有，对工作非常有帮助。当然TINA-TI也可以仿真射频电路，后续有时间可以讲解LNA的仿真设计。最值得期待的是不光是TI，未来还有很多其他的原厂也会陆续推出基于TINA的模型，让我们拭目以待。
评论